Private Sub CancelButton\_Click()

Unload UserForm1

End Sub

Private Sub OKButton\_Click()

Dim TextCells As Range

Dim cell As Range

Dim Text As String

Dim i As Long

' Ein Objekt nur mit Textkonstanten anlegen

On Error Resume Next

Set TextCells = Selection.SpecialCells(xlConstants, xlTextValues)

' Bildschirmaktualisierung deaktivieren

Application.ScreenUpdating = False

' Die Zellen durchlaufen

For Each cell In TextCells

Text = cell.Value

Select Case True

Case OptionLower 'kleinbuchstaben

cell.Value = LCase(cell.Value)

Case OptionUpper 'GROSSBUCHSTABEN

cell.Value = UCase(cell.Value)

Case OptionProper 'Gemischt

cell.Value = WorksheetFunction.Proper(cell.Value)

Case OptionSentence 'Erstes Zeichen groß

Text = UCase(Left(cell.Value, 1))

Text = Text & LCase(Mid(cell.Value, 2, Len(cell.Value)))

cell.Value = Text

Case OptionToggle 'uMKEHREN

For i = 1 To Len(Text)

If Mid(Text, i, 1) Like "[A-Z]" Then

Mid(Text, i, 1) = LCase(Mid(Text, i, 1))

Else

Mid(Text, i, 1) = UCase(Mid(Text, i, 1))

End If

Next i

cell.Value = Text

End Select

Next

' Dialogfeld entladen

Unload UserForm1

End Sub